Uses wodXMPP ActiveX component

Dim WithEvents wodXMPP1 As wodXMPPCom
Private Sub Form_Load()
    Set wodXMPP1 = New wodXMPPCom
    
    wodXMPP1.Login = "JID__username@domain.com"
    wodXMPP1.Password = "JID__password"
    'Connect to Jabber/XMPP server.
    wodXMPP1.Connect
End Sub

'Connected Event fires when wodXMPP connects to remote server.
Private Sub wodXMPP1_Connected()
    'When Connected Event is fired, we can send authorization request for a new contact.
    'In this example we will do that using button on our form (check Command1_Click).
    MsgBox "Connected"
End Sub

'ContactAuthRequest Event fires when new contact requests authorization to add you to his contact list.
Private Sub wodXMPP1_ContactAuthRequest(ByVal Contact As WODXMPPCOMLib.IXMPPContact, Action As WODXMPPCOMLib.XMPPActionsEnum)
    Dim jid As String
    
    jid = Contact.jid
    Dim i As Integer
    i = InStr(1, jid, "/")
    If i > 1 Then jid = Left$(jid, i - 1)
    
    i = InStr(1, jid, " ")
    If i > 1 Then jid = Left$(jid, i - 1)
    
    If MsgBox("Authorize " & jid & " to add you to his contact list?", vbYesNo + vbQuestion, "Authorization request") = vbYes Then
        Action = Allow
    End If
End Sub

'Disconnected Event fires when wodXMPP disconnects from server.
Private Sub wodXMPP1_Disconnected(ByVal ErrorCode As Long, ByVal ErrorText As String)
    'Inside Disconnected Event we can check for an error using ErrorText and ErrorCode variable.
    If ErrorCode <> 0 Then
        MsgBox "Error: " & ErrorText
    End If
End Sub

Private Sub Command1_Click()
    Dim cont As XMPPContact
    'Select which contact you want to add to your contact list.
    Set cont = wodXMPP1.Contacts.Add("contact_JID@domain.com")
    'Send authorization request to the selected contact.
    cont.Subscribe
End Sub

Uses wodXMPP ActiveX component

Dim WithEvents wodXMPP1 As WODXMPPCOMLib.wodXMPPCom
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    wodXMPP1 = New WODXMPPCOMLib.wodXMPPCom

    wodXMPP1.Login = "JID__username@domain.com"
    wodXMPP1.Password = "JID__password"
    'Connect to Jabber/XMPP server.
    wodXMPP1.Connect()
End Sub

'Connected Event fires when wodXMPP connects to remote server.
Private Sub wodXMPP1_Connected() Handles wodXMPP1.Connected
    'When Connected Event is fired, we can send authorization request for a new contact.
    'In this example we will do that using button on our form (check Command1_Click).
    MsgBox("Connected")
End Sub

'ContactAuthRequest Event fires when new contact requests authorization to add you to his contact list.
Private Sub wodXMPP1_ContactAuthRequest(ByVal Contact As WODXMPPCOMLib.XMPPContact, ByRef Action As WODXMPPCOMLib.XMPPActionsEnum) Handles wodXMPP1.ContactAuthRequest
    Dim jid As String

    jid = Contact.JID
    Dim i As Integer
    i = InStr(1, jid, "/")
    If i > 1 Then jid = Strings.Left(jid, i - 1)

    i = InStr(1, jid, " ")
    If i > 1 Then jid = Strings.Left(jid, i - 1)

    If MsgBox("Authorize " & jid & " to add you to his contact list?", MsgBoxStyle.YesNo + MsgBoxStyle.Question, "Authorization request") = MsgBoxResult.Yes Then
        Action = WODXMPPCOMLib.XMPPActionsEnum.Allow
    End If
End Sub

'Disconnected Event fires when wodXMPP disconnects from server.
Private Sub wodXMPP1_Disconnected(ByVal ErrorCode As Integer, ByVal ErrorText As String) Handles wodXMPP1.Disconnected
    'Inside Disconnected Event we can check for an error using ErrorText and ErrorCode variable.
    If ErrorCode <> 0 Then
        MsgBox("Error: " & ErrorText)
    End If
End Sub

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Dim cont As WODXMPPCOMLib.XMPPContact
    'Select which contact you want to add to your contact list.
    cont = wodXMPP1.Contacts.Add("contact_JID@domain.com")
    'Send authorization request to the selected contact.
    cont.Subscribe()
End Sub

Uses wodXMPP ActiveX component

WODXMPPCOMLib.wodXMPPCom wodXMPP1;
private void Form1_Load(System.Object sender, System.EventArgs e)
{
    wodXMPP1 = new WODXMPPCOMLib.wodXMPPCom();
    wodXMPP1.Connected += new WODXMPPCOMLib._IwodXMPPComEvents_ConnectedEventHandler(wodXMPP1_Connected);
    wodXMPP1.ContactAuthRequest += new WODXMPPCOMLib._IwodXMPPComEvents_ContactAuthRequestEventHandler(wodXMPP1_ContactAuthRequest);
    wodXMPP1.Disconnected += new WODXMPPCOMLib._IwodXMPPComEvents_DisconnectedEventHandler(wodXMPP1_Disconnected);

    wodXMPP1.Login = "JID__username@domain.com";
    wodXMPP1.Password = "JID__password";
    //Connect to Jabber/XMPP server.
    wodXMPP1.Connect(null);
}

//Connected Event fires when wodXMPP connects to remote server.
private void wodXMPP1_Connected()
{
    //When Connected Event is fired, we can send authorization request for a new contact.
    //In this example we will do that using button on our form (check Command1_Click).
    MessageBox.Show("Connected");
}

//ContactAuthRequest Event fires when new contact requests authorization to add you to his contact list.
private void wodXMPP1_ContactAuthRequest(WODXMPPCOMLib.XMPPContact Contact, ref WODXMPPCOMLib.XMPPActionsEnum Action)
{
    string[] jid;
    jid = Contact.JID.Split((" ").ToCharArray());

    if (MessageBox.Show("Authorize " + jid[0] + " to add you to his contact list?", "Authorization request...", System.Windows.Forms.MessageBoxButtons.YesNo) == DialogResult.Yes)
    {
        Action = WODXMPPCOMLib.XMPPActionsEnum.Allow;
    }
}

//Disconnected Event fires when wodXMPP disconnects from server.
private void wodXMPP1_Disconnected(int ErrorCode, string ErrorText)
{
    //Inside Disconnected Event we can check for an error using ErrorText and ErrorCode variable.
    if (ErrorCode != 0)
    {
        MessageBox.Show("Error: " + ErrorText);
    }
}

private void button1_Click(object sender, EventArgs e)
{
    WODXMPPCOMLib.XMPPContact cont;
    //Select which contact you want to add to your contact list.
    cont = wodXMPP1.Contacts.Add("contact_JID@domain.com");
    //Send authorization request to the selected contact.
    cont.Subscribe();
}